Function Collection (VBScript)
Function Collection (VBScript)
Introduction
- Introduction
Functions

GetComputerName

VBScript

This function returns the name of the computer (i.e. the host hame) the current script (i.e. the SwyxWare) is running on.

Please see the Introduction chapter for some usage instructions.

''-------------------------------------------------------------------
'' Name:     GetComputerName
''           ===============
'' 
'' Returns the name of the machine/computer this script (i.e. the SwyxWare) is running on.
'' 
'' return value:
''      string      computer name
''
''--------------------------------------------------------------------
Function GetComputerName()
    PBXScript.OutputTrace "---------> GetComputerName"

    Dim sReturn
    sReturn = ""

    On Error Resume Next

    Dim ob
    Set ob = CreateObject("WScript.Network")

    If err <> 0 Then
        PBXScript.OutputTrace "Error instanziating 'WScript.Network'! (" & err & ")"
        PBXScript.OutputTrace err.description
    Else
        sReturn = ob.ComputerName
        If err <> 0 Then
            PBXScript.OutputTrace "Error getting property 'ComputerName'! (" & err & ")"
            PBXScript.OutputTrace err.description
        End If
    End If
    Set ob = Nothing 

    GetComputerName = sReturn

    PBXScript.OutputTrace "sReturn = " & sReturn
    PBXScript.OutputTrace "<--------- GetComputerName"
End Function

This function makes use of the Server Script API function PBXScript.OutputTrace to write trace information into the SwyxServer trace file.

This function was initially posted into this forum topic.