Function: IsRedirectionLoopConfigured

[Tom Wellige]

The following function returns True if the current script user has an unconditional redirection to a user configured, where the current call already has been (in his call routing).

There is another function IsLoopConfigured available, following another approach to identify an existing call loop.

Please take a look into the How to avoid loops topic for more details.

To use the function within your call routing script just copy&paste it, as also the used GetUserNameFromExtension function, into the "Start" block and call it afterwards within an "Evaluate" block.

 

'----------------------------------------------------------------  
' IsRedirectionLoopConfigured 
'  
' Checks if the undonditional redirection target of the script user is
' already in the PreviousScripts list, i.e. the call was previously already in that user's call routing.
'  
' Parameter:
'  
' Return:
'	boolean 
'----------------------------------------------------------------
Function IsRedirectionLoopConfigured
	PBXScript.OutputTrace "-------------> IsRedirectionLoopConfigured"

	Dim bReturn
	bReturn = False

	If PBXUser.UnconditionalRedirect Then

		Dim sRedirectToUser
		sRedirectToUser = GetUserNameFromExtension(PBXUser.UnconditionalRedirectNumber)

		Dim Script
		For Each Script In PBXScript.PreviousScripts

			PBXScript.OutputTrace "Found user " & User.Name

			If sRedirectToUser = Script.UserName Then 
				PBXScript.OutputTrace "Found redirection target in the PreviousScripts list. So this is most likely a loop!"
				bReturn = True
			End If

		Next

	End If

	IsRedirectionLoopConfigured = bReturn

	PBXScript.OutputTrace "bReturn = " & bReturn
	PBXScript.OutputTrace "<------------- IsRedirectionLoopConfigured"
End Function